Batch Files

=== rp.bat ===

setlocal enabledelayedexpansion
for %%a in (*) do (
set f=%%a
set f=!f:^(=!
set f=!f:^)=!
ren "%%a" "!f!" ) 

Removes Parenthesis from file names in the current directory. 

Video demonstration:

=== ===

=== specs.bat ===

@echo off

set osInfo=wmic os get caption, OSArchitecture
set cpuInfo=wmic cpu get name
set ramInfo=wmic memorychip get Manufacturer, DeviceLocator, Partnumber, Speed
set motherboardInfo=wmic baseboard get Manufacturer, Product
set biosInfo=wmic bios get version, SMBIOSBIOSVersion
set gpuInfo=wmic PATH Win32_VideoController get Name, DriverVersion
set driveInfo=wmic diskdrive get model, size, name, partitions
set partitionInfo=wmic partition get name, size
set volumeInfo=wmic volume get filesystem, driveletter, name, capacity

FOR /F "usebackq" %%a IN (`wmic os get TotalVisibleMemorySize ^| findstr [0-9]`) DO Set "memInt=%%a" & set memUnit=KBs 
if %memInt% GEQ 4096 (set /a memFloat=memInt %% 1024 & set /a memInt/= 1024 & set memUnit=MBs)
if %memInt% GEQ 4096 (set /a memFloat=memInt %% 1024 & set /a memInt/= 1024 & set memUnit=GBs)
set /a memFloat=memFloat * 10 /1024
set totalMemory=%memInt% %memUnit%
if %memFloat% GTR 0 set totalMemory=%memInt%.%memFloat% %memUnit%

echo ========= OS ============== & %osInfo% 
echo ========= CPU ============= & %cpuInfo%
echo ========= RAM ============= & %ramInfo% & echo Total Memory %totalMemory%
echo ========= Motherboard ===== & %motherboardInfo% & %biosInfo%
echo ========= GPU ============= & %gpuInfo%
REM echo ========= Storage ========= & echo Drive & %driveInfo% & echo Partition & %partitionInfo% & echo Volume & %volumeInfo%

pause

Running this script will use WMIC, a tool that comes with Windows by default, to query for the CPU, RAM, OS version, Motherboard, BIOS and GPU information that is available

By default storage information is commented out, remove the `REM` keyword near the bottom to uncomment the call for storage information, doing this will show drive, partition, and volume information

Sample: 

note: the WMIC tool was deprecated, it may be removed from future versions of Windows, as of late 2022 Windows 10 and 11 still seems to ship with the tool
https://docs.microsoft.com/en-us/windows/deployment/planning/windows-10-deprecated-features